
<%
'
'*** Classe Botao ********************************************************************
'
Class Botao
	Public rotulo
	Public funcaojs
	Public largura
	Public visivel
	Public lado      '1-Esquerdo; 2-Direito
	
	'---------------------------------------------------------------------------------
	Private Sub Class_Initialize()
		rotulo = ""
		funcaojs = ""
		largura = 0
		visivel = true
	End Sub
	
	'---------------------------------------------------------------------------------
	Private Sub Class_Terminate()
	End Sub
	
End Class
'
'*** Classe Toolbar ********************************************************************
'
Class Toolbar
	Private hiBgColor
	Private lowBgColor
	Private borderColor
	Private border
	Private fontFamily
	Private fontSize
	Private fontBold
	Private fontItalic
	Private hiFontColor
	Private lowFontColor
	Private frameScripts
	Private useSeguranca
	Private usuario
	Private topSeparator
	Private botSeparator
	Private colBotoes()
	Private indBotoes
	Private contEsquerdo
	Private contDireito
	Private backColor
	
	'---------------------------------------------------------------------------------
	Private Sub Class_Initialize()
		indItens = 0
		hiBgColor = "#CCDDDD"
		lowBgColor = "#669999"
		borderColor = "#000000"
		backColor = "#99cccc"
		border = true
		fontFamily = "Verdana, Arial, Times"
		fontSize = 8
		fontBold = true
		fontItalic = false
		hiFontColor = "#000000"
		lowFontColor = "#FFFFFF"
		frameScripts = "corpo"
		useSeguranca = false
		topSeparator = true
		botSeparator = false
		' Atribuição deveria passar uma referência para o objeto representando o usuário logado
		set usuario = nothing
		Redim colBotoes(5)
		indBotoes = 0
		contEsquerdo = 0
		contDireito = 0
	End Sub
	
	'---------------------------------------------------------------------------------
	Private Sub Class_Terminate()
		dim i
		for i = 0 to indBotoes - 1
			set colBotoes(i) = nothing
		next
		set usuario = nothing
	End Sub
	
	'---------------------------------------------------------------------------------
	Public Sub AddBotaoAssociacao(rotulo, funcaojs, largura, programa, operacao)
		dim botao
		set botao = new Botao

		botao.lado 		= 1 'ESQUERDO
		botao.rotulo 	= Replace(rotulo, " ", "&nbsp;")
		botao.funcaojs = funcaojs
		botao.largura 	= largura
		' Deveria retornar o resultado da verificacao da liberação do usuário para PROGRAMA e OPERACAO
		botao.visivel 	= true
		
		if indBotoes = UBound(colBotoes)-1 then
			redim preserve colBotoes(UBound(colBotoes)+5)
		end if
		set colBotoes(indBotoes) = botao
		indBotoes = indBotoes + 1
		contEsquerdo = contEsquerdo + 1
		
		set botao = nothing
	End Sub
	
	'---------------------------------------------------------------------------------
	Public Sub AddBotaoOperacao(rotulo, funcaojs, largura, programa, operacao)
		dim botao
		set botao = new Botao
		
		botao.lado 		= 2 'DIREITO
		botao.rotulo 	= Replace(rotulo, " ", "&nbsp;")
		botao.funcaojs = funcaojs
		botao.largura 	= largura
		' Deveria retornar o resultado da verificacao da liberação do usuário para PROGRAMA e OPERACAO
		botao.visivel 	= true
		
		if indBotoes = UBound(colBotoes)-1 then
		redim preserve colBotoes(UBound(colBotoes)+5)
		end if
		set colBotoes(indBotoes) = botao
		indBotoes = indBotoes + 1
		contDireito = contDireito + 1
		
		set botao = nothing
	End Sub
	
	'---------------------------------------------------------------------------------
	Public Sub SetCores(fonteAtivo, fonteInativo, fundoAtivo, fundoInativo, borda, back)
		hiBgColor 	 = fundoAtivo
		lowBgColor 	 = fundoInativo
		borderColor  = borda
		hiFontColor  = fonteAtivo
		lowFontColor = fonteInativo
		backColor	 = back
	End Sub
	
	'---------------------------------------------------------------------------------
	Public Sub SetFonte(familia, tamanho, negrito, italico)
		fontFamily 	= familia
		fontSize 	= tamanho
		fontBold 	= negrito
		fontItalic 	= italico
	End Sub
	
	'---------------------------------------------------------------------------------
	Public Sub Configura(frame, top, bottom, borda, seguranca)
		frameScripts = frame
		topSeparator = top
		botSeparator = bottom
		border 		 = borda
		useSeguranca  = seguranca
		
		if useSeguranca then 
			'Ativa seguranca
		end if	
	End Sub

	'---------------------------------------------------------------------------------
	Public Sub Monta()
		MontaCSS
		MontaEstrutura
		MontaAssociacoes
		MontaOperacoes
		Finaliza
	End Sub
	
	'---------------------------------------------------------------------------------
	Private Sub MontaCSS()
	%>
		<style type="text/css">
		body {
			background-color: <%= backColor %>;
			margin-left : 5px;
			margin-bottom : 0px;
			margin-right : 5px;
			margin-top : 0px;
		}	
		td.MetToolbarBotao {
			background-color: <%= lowBgColor %>;
			color: <%= lowFontColor %>;
			cursor: pointer;
			font-family: <%= fontFamily %>;
			font-size: <%= fontSize %>pt;
			font-weight: <% if fontBold then Response.Write("bold") else Response.Write("normal") %>;
			font-style : <% if fontItalic then Response.Write("italic") else Response.Write("normal") %>;
			text-align: center;
			border : <% if border then Response.Write("1px solid") else Response.Write("0px")%>;
			border-color : <%= borderColor %>;
			border-right-style : none;
			border-right-width : 0px;
		}
		
		td.MetToolbarUltBotao {
			background-color: <%= lowBgColor %>;
			color: <%= lowFontColor %>;
			cursor: pointer;
			font-family: <%= fontFamily %>;
			font-size: <%= fontSize %>pt;
			font-weight: <% if fontBold then Response.Write("bold") else Response.Write("normal") %>;
			font-style: <% if fontItalic then Response.Write("italic") else Response.Write("normal") %>;
			text-align: center;
			border : <% if border then Response.Write("1px solid") else Response.Write("0px")%>;
			border-color : <%= borderColor %>;
		}
		
		td.MetToolbarSeparador {
			background-color: transparent;
		}
		
		a:active,a:visited,a:link {
			color: <%= lowFontColor %>; 
			text-decoration: none
		}
		</style>
	<%
	End Sub	

	'---------------------------------------------------------------------------------
	Private Sub MontaEstrutura()
	%>
		<table width="100%" border=0 cellpadding="0" cellspacing="0">
		<%if topSeparator and (contEsquerdo + contDireito) > 0 then %>
			<tr><td colspan=2><hr size=1></td></tr>
		<%end if%>	
		<tr>
	<%
	End Sub
	
	'---------------------------------------------------------------------------------
	Private Sub MontaAssociacoes()
		dim i, esquerdo, classe
		esquerdo = 0
		classe = ""
		if contEsquerdo > 0 then
		%>
		<td align="left" class="separador">
			<table border=1 cellpadding="0" cellspacing="0" style="border-style:none;border-color:<%= borderColor %>">
			<tr>
			<%
			for i = 0 to indBotoes - 1
				if colBotoes(i).lado = 1 then
					esquerdo = esquerdo + 1
					if colBotoes(i).visivel then
						if esquerdo = contEsquerdo then classe = "MetToolbarUltBotao" else classe = "MetToolbarBotao"
						%>
						<td class="<%= classe %>" width="<%= colBotoes(i).largura %>" height="20px" onclick="parent.<%= frameScripts %>.<%= colBotoes(i).funcaojs %>" onmouseover="this.style.backgroundColor='<%= hiBgColor %>';this.style.color='<%= hiFontColor %>'" onmouseout="this.style.backgroundColor='<%= lowBgColor %>';this.style.color='<%= lowFontColor %>'"> <%= colBotoes(i).rotulo %></td>
						<%
					end if
				end if	
			next
			%>
			</tr>
			</table>
		</td>
		<%
		end if
	End Sub
	
	'---------------------------------------------------------------------------------
	Private Sub MontaOperacoes()
		dim i, direito, classe
		direito = 0
		classe = ""
		if contDireito > 0 then
		%>
		<td align="right" class="separador">
			<table border=0 cellpadding="0" cellspacing="0">
			<tr>
			<%
			for i = 0 to indBotoes - 1
				if colBotoes(i).lado = 2 then
					direito = direito + 1
					if colBotoes(i).visivel then
						if direito = contDireito then classe = "MetToolbarUltBotao" else classe = "MetToolbarBotao"
						%>
						<td class="<%= classe %>" width="<%= colBotoes(i).largura %>" height="20px" onclick="parent.<%= frameScripts %>.<%= colBotoes(i).funcaojs %>" onmouseover="this.style.backgroundColor='<%= hiBgColor %>';this.style.color='<%= hiFontColor %>'" onmouseout="this.style.backgroundColor='<%= lowBgColor %>';this.style.color='<%= lowFontColor %>'"> <%= colBotoes(i).rotulo %></td>
						<%
					end if
				end if	
			next
			%>
			</tr>
			</table>
		</td>
		<%	
		end if
	End Sub
	
	'---------------------------------------------------------------------------------
	Private Sub Finaliza()
	%>
		</tr>
		<%if botSeparator and (contEsquerdo + contDireito) > 0 then %>
			<tr><td colspan=2><hr size=1></td></tr>
		<%end if%>	
		</table>
	<%
	End Sub

End Class
%>